Qt 4.4: plugandpaint.pro Example File (tools/plugandpaint/plugandpaint.pro)

|  | Home · All Classes · Main Classes · Grouped Classes · Modules · Functions |

# plugandpaint.pro Example File
tools/plugandpaint/plugandpaint.pro

     HEADERS        = interfaces.h \
                      mainwindow.h \
                      paintarea.h \
                      plugindialog.h
     SOURCES        = main.cpp \
                      mainwindow.cpp \
                      paintarea.cpp \
                      plugindialog.cpp
     LIBS           = -L$${QT_BUILD_TREE}/examples/tools/plugandpaint/plugins -lpnp_basictools

     if(!debug_and_release|build_pass):CONFIG(debug, debug|release) {
        mac:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)_debug
        win32:LIBS = $$member(LIBS, 0) $$member(LIBS, 1)d
     }

     # install
     target.path = $$[QT_INSTALL_EXAMPLES]/tools/plugandpaint
     sources.files = $$SOURCES $$HEADERS $$RESOURCES $$FORMS plugandpaint.pro
     sources.path = $$[QT_INSTALL_EXAMPLES]/tools/plugandpaint
     INSTALLS += target sources